Advanced Skinning

Often I’ll skin characters completely manually, especially simple characters. Even though heat mapping seems to get characters skinned quickly, by the time I’ve finished weighting I’ll usually have weighted most of the character manually except in hires geo examples.

1. Reset Settings
2. Bind To: Selected Joints
3. Max Influences: 3

Also skeletons that aren’t joined must be weighted more manually than skeletons that have a visual connection. This is because maya is smart if the joints are connected, less so if the joints are hovering and not visually joined.

The video shows in more detail…

Heat Binding introduced in Maya 2014 uses a very clever algorythm that intelligently recognises the form of objects to skin via surface volume and not closest points to joints. It only works in certain conditions. Non manifold geometry for example will break it.

Geodesic Voxel (2015 only) is touted by Autodesk as more versatile version of heat binding. It converts the mesh into voxels allowing us to heat bind meshes that usually wouldn’t be suitable with heat binding.

From my tests I prefer Heat Mapping, it’s faster and gives better results however Geodesic Voxel is a good fallback if heat mapping fails. Both methods require bones inside a mesh like a characters body and for the polygon normals to point outwards correctly. For any fast simple objects I still use “closest distance”.

A work around is to bind two identical meshes, one with heat or geodesic binding the other with closest distance. Then transfer the weights from the heat/geo to the closest distance. This will work around the issue and give us heat/geo weighting without moving the vertices.

2 meshes
Bind Heat Map
List Influenced Joints
Bind Regular
Copy Skin
Delete Heat Mesh

I use 80% of my numerical weighting in the Max Script Window and 20% in the component editor.

Copy the following script to the shelf (.mel)

//////////////////////////////////////////
//Select meshes to transfer weight to, then shift-select the mesh with weights, then run this script

string $userSel[] = `ls -sl`;

if(`size($userSel)` > 1)
{

select $userSel[((`size($userSel)`) - 1)];
string $cageMesh[] = `ls -sl`;

select $userSel;
select -tgl $cageMesh;
string $pieces[] = `ls -sl`;

//get inputs of weights in skin
string $theJoints[] = `skinCluster -q -wi $cageMesh`;

if(`size($theJoints)` > 0 && $cageMesh[0] != "")
{

int $counter;
int $sizer = size($pieces);

for ($counter = 0; $counter < $sizer; $counter++)
{

///////////////////////////////////////////////////////////////////////////////////////
//Determine if skinCluster exists on piece
string $skins[] ;
clear $skins ;

string $hist[] = `listHistory -pdo 1 -il 2 $pieces[$counter]` ;
string $h ;

for ($h in $hist)
{
if (nodeType($h) == "skinCluster")
{
$skins[size($skins)] = $h ;
}//end of if skinCluster type exists
}//end of for loop through history


/////////////////////////////////////////////////////////////////////////////////////////
//If skinCluster Doesn't exist, add skinCluster
if(`size($skins)` == 0)
{
select $pieces[$counter] $theJoints;
newSkinCluster "-tsb -mi 10 -dr 10" ;
}//end of apply skinCluster if none found


//////////////////////////////////////////////////////////////////////////////////////////
//Add all influences from cageMesh
int $counterInf;
int $sizerInf = size($theJoints);
string $pieceJoints[] = `skinCluster -q -wi $pieces[$counter]`;

for ($counterInf = 0; $counterInf < $sizerInf; $counterInf++)
{
int $found = stringArrayContains($theJoints[$counterInf], $pieceJoints);
if($found == 0){skinCluster -e -ai $theJoints[$counterInf] $skins[0];}
}//end of for loop through adding all cageJoints


///////////////////////////////////////////////////////////////////////////////////////////
//Remove extra joints that don't match those in cageMesh skinCluster
string $theJoints[] = `skinCluster -q -wi $cageMesh`;
string $pieceJoints[] = `skinCluster -q -wi $pieces[$counter]`;
string $diffJoints[] = stringArrayRemove($theJoints, $pieceJoints);

int $counterInf;
int $sizerInf = size($diffJoints);

if(`size($diffJoints)` > 0)
{
for ($counterInf = 0; $counterInf < $sizerInf; $counterInf++)
{
skinCluster -e -ri $diffJoints[$counterInf] $skins[0];
}//end of for loop through removing extra joints
}//end of if any joints are different


//////////////////////////////////////////////////////////////////////////////////////////
//Transfer the Weights
select $cageMesh $pieces[$counter];
copySkinWeights -noMirror -surfaceAssociation closestPoint -influenceAssociation closestJoint -influenceAssociation oneToOne -influenceAssociation name -normalize;


//////////////////////////////////////////////////////////////////////////////////////////
//Finalize
print ("\nSkin Applied/Weights Transferred: " + ($counter + 1) + "/" + $sizer);

}//end of loop through pieces

select $userSel;

}//end of if there is a skinCluster to copy from

}//end of if user has selected enough items

This plugin can be downloaded for free from BraveRabbit...
http://www.braverabbit.de/playground/?p=915